「ほっ」と。キャンペーン
(VB.Net)時間用コンボボックスのユーザコントロールを作ってみた
業務で必要だったので時間入力用コンボボックスをユーザコントロールで作ってみました。
機能は
コンボボックスでプロパティで指定された区切り時間を選択できる。
直接入力も可能。(その場合は、入力チェックを行う)
直接入力とドロップダウンリストのみで選ぶことが選択可能。
というくらいの機能です。
機能やプロパティ、イベントの定義は最小限にしています。

ユーザコントロール TimeComboBox クラスを作り、デザイナでForms.ComboBoxを "combo" という名前で配置します。

下記がソースです。(文字数の関係上ハイライトはしていません。。)

Imports System.ComponentModel

''' <summary>
''' 時間入力用のコンボボックス。
''' </summary>
''' <remarks></remarks>
Public Class TimeComboBox
''' <summary>
''' コンボボックスの時間の単位
''' </summary>
''' <remarks></remarks>
Public Enum TimeSpan_Enum
''' <summary>5分単位</summary>
FiveMinute = 5
''' <summary>10分単位</summary>
TenMinute = 10
''' <summary>15分単位</summary>
FifteenMinute = 15
''' <summary>20分単位</summary>
TwentyMinute = 20
''' <summary>25分単位</summary>
TwentyFiveMinute = 25
''' <summary>30分単位</summary>
ThirtyMinute = 30
''' <summary>1時間単位</summary>
SixtyMinute = 60
End Enum

'コンボボックスの時間単位
Private m_ComboTimeSpan As TimeSpan_Enum = TimeSpan_Enum.ThirtyMinute

'時間の値
Private m_BeforeValue As DateTime


''' <summary>
''' コンボボックスで選択、もしくは入力された時間の値を取得、設定する。
''' (年月日部分は無効な情報なので、無視すること)
''' </summary>
''' <value></value>
''' <returns></returns>
''' <remarks></remarks>
Public Property Value() As DateTime
Get
check()
Return m_BeforeValue
End Get
Set(ByVal value As DateTime)
Me.combo.Text = value.Hour.ToString("0") & ":" & value.Minute.ToString("00")
End Set
End Property

''' <summary>
''' コンボボックスに表示する時間の間隔
''' </summary>
''' <value></value>
''' <returns></returns>
''' <remarks></remarks>
Public Property ComboTimeSpan() As TimeSpan_Enum
Get
Return m_ComboTimeSpan
End Get
Set(ByVal value As TimeSpan_Enum)
m_ComboTimeSpan = value
InitComboList()
End Set
End Property

''' <summary>
''' ドロップダウンのスタイル
''' </summary>
''' <value></value>
''' <returns></returns>
''' <remarks></remarks>
Public Property DropDownStyle() As ComboBoxStyle
Get
Return Me.combo.DropDownStyle
End Get
Set(ByVal value As ComboBoxStyle)
Me.combo.DropDownStyle = value
End Set
End Property


''' <summary>
''' コンボボックスの値を指定された時間間隔でセットする。
''' </summary>
''' <remarks></remarks>
Private Sub InitComboList()
Dim max As Integer = 1440 / Me.m_ComboTimeSpan - 1
Dim comboItem(max) As String

For i As Integer = 0 To max
Dim minute As Integer = i * Me.m_ComboTimeSpan
Dim h As Integer = CInt(Math.Floor(minute / 60))
Dim m As Integer = minute Mod 60
comboItem(i) = h.ToString("0") & ":" & m.ToString("00")
Next

Me.combo.Items.Clear()
Me.combo.Items.AddRange(comboItem)
End Sub


''' <summary>
''' コンボボックスで選択されたとき
''' </summary>
''' <param name="sender"></param>
''' <param name="e"></param>
''' <remarks></remarks>
Private Sub combo_SelectedIndexChanged(ByVal sender As Object, ByVal e As System.EventArgs) Handles combo.SelectedIndexChanged
Dim dtm As DateTime
If DateTime.TryParse(combo.Text, dtm) Then
Me.m_BeforeValue = dtm
End If
End Sub

''' <summary>
''' Validated
''' </summary>
''' <param name="sender"></param>
''' <param name="e"></param>
''' <remarks></remarks>
Private Sub combo_Validated(ByVal sender As Object, ByVal e As System.EventArgs) Handles combo.Validated
'イベント発生
RaiseEvent ValueChanged(Me, New EventArgs())
End Sub

''' <summary>
''' Validating
''' </summary>
''' <param name="sender"></param>
''' <param name="e"></param>
''' <remarks></remarks>
Private Sub combo_Validating(ByVal sender As Object, ByVal e As System.ComponentModel.CancelEventArgs) Handles combo.Validating
If Me.combo.SelectedIndex < 0 Then
If Not check() Then
MessageBox_Rhythm.Show("時間の入力の形式が間違っています。" & vbNewLine & "正しい時間の形式で入力してください。", EnumDef.MessageBoxIconMode.Warn)
combo.Text = Me.m_BeforeValue.Hour.ToString("0") & ":" & Me.m_BeforeValue.Minute.ToString("00")
e.Cancel = True
End If
End If
End Sub

''' <summary>
''' 入力チェック。値がOKならが、メンバ変数m_BeforeValueと、コンボボックスのTextプロパティにセットする。
''' </summary>
''' <returns></returns>
''' <remarks></remarks>
Private Function check() As Boolean
Dim dtm As DateTime
If DateTime.TryParse(combo.Text, dtm) Then
Me.m_BeforeValue = dtm
Me.combo.Text = dtm.Hour.ToString("0") & ":" & dtm.Minute.ToString("00")
Return True
Else
Return False
End If
End Function

#Region "イベント定義"

''' <summary>Valueプロパティが変更されたときに発生するイベント</summary>
<Description("Valueプロパティが変更されたときに発生するイベント。"), _
Category("プロパティ変更")> _
Public Event ValueChanged(ByVal sender As Object, ByVal e As System.EventArgs)

#End Region

End Class


外観はこんな感じになります。
e0091163_19155043.jpg
[PR]
by jehoshaphat | 2008-12-20 19:21 | .Net開発 | Trackback | Comments(0)
トラックバックURL : http://jehupc.exblog.jp/tb/9247683
トラックバックする(会員専用) [ヘルプ]
※このブログはトラックバック承認制を適用しています。 ブログの持ち主が承認するまでトラックバックは表示されません。


<< (VB.Net)MD5のハッシ... (VB.Net)RichTex... >>